File Manager

✏️ /

// Copyright 2017 The Go Authors. All rights reserved.
// Use of this source code is governed by a BSD-style
// license that can be found in the LICENSE file.

#include "textflag.h"

// castagnoliUpdate updates the non-inverted crc with the given data.

// func castagnoliUpdate(crc uint32, p []byte) uint32
TEXT ·castagnoliUpdate(SB),NOSPLIT,$0-36
	MOVWU	crc+0(FP), R9  // CRC value
	MOVD	p+8(FP), R13  // data pointer
	MOVD	p_len+16(FP), R11  // len(p)

update:
	CMP	$16, R11
	BLT	less_than_16
	LDP.P	16(R13), (R8, R10)
	CRC32CX	R8, R9
	CRC32CX	R10, R9
	SUB	$16, R11

JMP	update

less_than_16:
	TBZ	$3, R11, less_than_8

MOVD.P	8(R13), R10
	CRC32CX	R10, R9

less_than_8:
	TBZ	$2, R11, less_than_4

MOVWU.P	4(R13), R10
	CRC32CW	R10, R9

less_than_4:
	TBZ	$1, R11, less_than_2

MOVHU.P	2(R13), R10
	CRC32CH	R10, R9

less_than_2:
	TBZ	$0, R11, done

MOVBU	(R13), R10
	CRC32CB	R10, R9

done:
	MOVWU	R9, ret+32(FP)
	RET

// ieeeUpdate updates the non-inverted crc with the given data.

// func ieeeUpdate(crc uint32, p []byte) uint32
TEXT ·ieeeUpdate(SB),NOSPLIT,$0-36
	MOVWU	crc+0(FP), R9  // CRC value
	MOVD	p+8(FP), R13  // data pointer
	MOVD	p_len+16(FP), R11  // len(p)

update:
	CMP	$16, R11
	BLT	less_than_16
	LDP.P	16(R13), (R8, R10)
	CRC32X	R8, R9
	CRC32X	R10, R9
	SUB	$16, R11

JMP	update

less_than_16:
	TBZ $3, R11, less_than_8

MOVD.P	8(R13), R10
	CRC32X	R10, R9

less_than_8:
	TBZ	$2, R11, less_than_4

MOVWU.P	4(R13), R10
	CRC32W	R10, R9

less_than_4:
	TBZ	$1, R11, less_than_2

MOVHU.P	2(R13), R10
	CRC32H	R10, R9

less_than_2:
	TBZ	$0, R11, done

MOVBU	(R13), R10
	CRC32B	R10, R9

done:
	MOVWU	R9, ret+32(FP)
	RET

Batal

⬅ hash 15 item

Nama	Tipe	Ukuran	Diubah	Aksi
🔵crc32.go	go	7.9 KB	2024-02-02 18:09	✏️ 👁️
🔵crc32_amd64.go	go	6.8 KB	2024-02-02 18:09	✏️ 👁️
📄crc32_amd64.s	s	5.4 KB	2024-02-02 18:09	✏️ 👁️
🔵crc32_arm64.go	go	1.2 KB	2024-02-02 18:09	✏️ 👁️
📄crc32_arm64.s	s	1.6 KB	2024-02-02 18:09	✏️ 👁️
🔵crc32_generic.go	go	2.5 KB	2024-02-02 18:09	✏️ 👁️
🔵crc32_otherarch.go	go	681 B	2024-02-02 18:09	✏️ 👁️
🔵crc32_ppc64le.go	go	2.2 KB	2024-02-02 18:09	✏️ 👁️
📄crc32_ppc64le.s	s	13.6 KB	2024-02-02 18:09	✏️ 👁️
🔵crc32_s390x.go	go	2.1 KB	2024-02-02 18:09	✏️ 👁️
📄crc32_s390x.s	s	7.6 KB	2024-02-02 18:09	✏️ 👁️
📄crc32_table_ppc64le.s	s	113.3 KB	2024-02-02 18:09	✏️ 👁️
🔵crc32_test.go	go	12.1 KB	2024-02-02 18:09	✏️ 👁️
🔵example_test.go	go	1 KB	2024-02-02 18:09	✏️ 👁️
🔵gen_const_ppc64le.go	go	4.5 KB	2024-02-02 18:09	✏️ 👁️

✏️ Rename